Commit dbf4ed89 authored by Max Filippov's avatar Max Filippov
Browse files

xtensa: add helpers for division, remainder and shifts 



Don't rely on libgcc presence, build own versions of the helpers with
correct ABI.

Signed-off-by: default avatarMax Filippov <jcmvbkbc@gmail.com>
parent 8c9ab55c

arch/xtensa/include/asm/asmmacro.h

+34 −0
Original line number Diff line number Diff line
@@ -191,6 +191,40 @@ 
#endif

	.endm



	.macro	do_nsau cnt, val, tmp, a

#if XCHAL_HAVE_NSA

	nsau	\cnt, \val

#else

	mov	\a, \val

	movi	\cnt, 0

	extui	\tmp, \a, 16, 16

	bnez	\tmp, 0f

	movi	\cnt, 16

	slli	\a, \a, 16

0:

	extui	\tmp, \a, 24, 8

	bnez	\tmp, 1f

	addi	\cnt, \cnt, 8

	slli	\a, \a, 8

1:

	movi	\tmp, __nsau_data

	extui	\a, \a, 24, 8

	add	\tmp, \tmp, \a

	l8ui	\tmp, \tmp, 0

	add	\cnt, \cnt, \tmp

#endif /* !XCHAL_HAVE_NSA */

	.endm



	.macro	do_abs dst, src, tmp

#if XCHAL_HAVE_ABS

	abs	\dst, \src

#else

	neg	\tmp, \src

	movgez	\tmp, \src, \src

	mov	\dst, \tmp

#endif

	.endm



#define XTENSA_STACK_ALIGNMENT		16



#if defined(__XTENSA_WINDOWED_ABI__)

arch/xtensa/lib/Makefile

+2 −0
Original line number Diff line number Diff line
@@ -4,5 +4,7 @@ 
#



lib-y	+= memcopy.o memset.o checksum.o \

	   ashldi3.o ashrdi3.o lshrdi3.o \

	   divsi3.o udivsi3.o modsi3.o umodsi3.o mulsi3.o \

	   usercopy.o strncpy_user.o strnlen_user.o

lib-$(CONFIG_PCI) += pci-auto.o

arch/xtensa/lib/ashldi3.S

0 → 100644
+28 −0
Original line number Diff line number Diff line 
/* SPDX-License-Identifier: GPL-2.0-or-later WITH GCC-exception-2.0 */

#include <linux/linkage.h>

#include <asm/asmmacro.h>

#include <asm/core.h>



#ifdef __XTENSA_EB__

#define uh a2

#define ul a3

#else

#define uh a3

#define ul a2

#endif /* __XTENSA_EB__ */



ENTRY(__ashldi3)



	abi_entry_default

	ssl	a4

	bgei	a4, 32, .Llow_only

	src	uh, uh, ul

	sll	ul, ul

	abi_ret_default



.Llow_only:

	sll	uh, ul

	movi	ul, 0

	abi_ret_default



ENDPROC(__ashldi3)

arch/xtensa/lib/ashrdi3.S

0 → 100644
+28 −0
Original line number Diff line number Diff line 
/* SPDX-License-Identifier: GPL-2.0-or-later WITH GCC-exception-2.0 */

#include <linux/linkage.h>

#include <asm/asmmacro.h>

#include <asm/core.h>



#ifdef __XTENSA_EB__

#define uh a2

#define ul a3

#else

#define uh a3

#define ul a2

#endif /* __XTENSA_EB__ */



ENTRY(__ashrdi3)



	abi_entry_default

	ssr	a4

	bgei	a4, 32, .Lhigh_only

	src	ul, uh, ul

	sra	uh, uh

	abi_ret_default



.Lhigh_only:

	sra	ul, uh

	srai	uh, uh, 31

	abi_ret_default



ENDPROC(__ashrdi3)

arch/xtensa/lib/divsi3.S

0 → 100644
+74 −0
Original line number Diff line number Diff line 
/* SPDX-License-Identifier: GPL-2.0-or-later WITH GCC-exception-2.0 */

#include <linux/linkage.h>

#include <asm/asmmacro.h>

#include <asm/core.h>



ENTRY(__divsi3)



	abi_entry_default

#if XCHAL_HAVE_DIV32

	quos	a2, a2, a3

#else

	xor	a7, a2, a3	/* sign = dividend ^ divisor */

	do_abs	a6, a2, a4	/* udividend = abs (dividend) */

	do_abs	a3, a3, a4	/* udivisor = abs (divisor) */

	bltui	a3, 2, .Lle_one	/* check if udivisor <= 1 */

	do_nsau	a5, a6, a2, a8	/* udividend_shift = nsau (udividend) */

	do_nsau	a4, a3, a2, a8	/* udivisor_shift = nsau (udivisor) */

	bgeu	a5, a4, .Lspecial



	sub	a4, a4, a5	/* count = udivisor_shift - udividend_shift */

	ssl	a4

	sll	a3, a3		/* udivisor <<= count */

	movi	a2, 0		/* quotient = 0 */



	/* test-subtract-and-shift loop; one quotient bit on each iteration */

#if XCHAL_HAVE_LOOPS

	loopnez	a4, .Lloopend

#endif /* XCHAL_HAVE_LOOPS */

.Lloop:

	bltu	a6, a3, .Lzerobit

	sub	a6, a6, a3

	addi	a2, a2, 1

.Lzerobit:

	slli	a2, a2, 1

	srli	a3, a3, 1

#if !XCHAL_HAVE_LOOPS

	addi	a4, a4, -1

	bnez	a4, .Lloop

#endif /* !XCHAL_HAVE_LOOPS */

.Lloopend:



	bltu	a6, a3, .Lreturn

	addi	a2, a2, 1	/* increment if udividend >= udivisor */

.Lreturn:

	neg	a5, a2

	movltz	a2, a5, a7	/* return (sign < 0) ? -quotient : quotient */

	abi_ret_default



.Lle_one:

	beqz	a3, .Lerror

	neg	a2, a6		/* if udivisor == 1, then return... */

	movgez	a2, a6, a7	/* (sign < 0) ? -udividend : udividend */

	abi_ret_default



.Lspecial:

	bltu	a6, a3, .Lreturn0 /* if dividend < divisor, return 0 */

	movi	a2, 1

	movi	a4, -1

	movltz	a2, a4, a7	/* else return (sign < 0) ? -1 : 1 */

	abi_ret_default



.Lerror:

	/* Divide by zero: Use an illegal instruction to force an exception.

	   The subsequent "DIV0" string can be recognized by the exception

	   handler to identify the real cause of the exception.  */

	ill

	.ascii	"DIV0"



.Lreturn0:

	movi	a2, 0

#endif /* XCHAL_HAVE_DIV32 */

	abi_ret_default



ENDPROC(__divsi3)